Bootable, TCP/IP network-capable DOS floppy

Here are the files from the floppy. This is a DOS 6.22 floppy instead of DOS 9x to avoid Win 9x from formatting partitions with a LOCK on them which cause problems when restoring images. Also, IO.SYS and MSDOS.SYS combined only take 70K as opposed to over 200K on a DOS 9x.

As I am no guru when it comes with DOS batch files, and I'd much rather spend time with Perl, Python, and the such, there are probably better ways to do things in the configuration files below. Also, I just started checking out JP Software's excellent 4DOS and 4NT shell replacement for COMMAND.COM because of its much richer batch features, so this stuff is probably better handled by 4DOS (http://www.jpsoftware.com).  Here is the boot image (use shareware WinImage to write it to a floppy.)

FILES

IO.SYS
MSDOS.SYS
4DOS.COM
4DOS.DAT
4DOS.INI
Config.sys
RAMDRIVE.SYS
SBIDE.SYS
TAISATAP.SYS
EMM386.EXE
FINDRAMD.EXE
HIMEM.SYS
IFSHLP.SYS
KEYB.COM
KEYBOARD.SYS
Autoexec.bat
PKUNZJR.COM
NCDOS.ZIP
NET.ZIP
PQMAGICT.ZIP
UTILS.ZIP
 

CONFIG.SYS

[menu]
menuitem=CD14,CDROM on IDE plug 1
menuitem=CD15,CDROM on IDE plug 2
menuitem=NOCD,No CDROM
menudefault=NOCD,30

[GENERAL]
device=himem.sys /testmem:off
device=emm386.exe noems
dos=high,umb
SHELL=A:\4DOS.COM /F /P

[CD14]
INCLUDE=GENERAL
devicehigh=sbide.sys /D:mscd001 /P:1F0,14

[CD15]
INCLUDE=GENERAL
devicehigh=sbide.sys /D:mscd001 /P:170,15

[NOCD]
INCLUDE=GENERAL

[COMMON]
devicehigh=IFSHLP.SYS
stacks=9,256
FILES=20
buffers=10
lastdrive=z
DEVICEHIGH=RAMDRIVE.SYS 4096 /E
 

AUTOEXEC.BAT

SET COMSPEC=A:\4DOS.COM

@ECHO OFF
FINDRAMD
if errorlevel=6 GOTO DRIVEF
if errorlevel=5 GOTO DRIVEE
if errorlevel=4 GOTO DRIVED
if errorlevel=3 GOTO DRIVEC
GOTO END

:DRIVEF
set ramdisk=F:\
GOTO MAIN

:DRIVEE
set ramdisk=E:\
GOTO MAIN

:DRIVED
set ramdisk=D:\
GOTO MAIN

:DRIVEC
set ramdisk=C:\
GOTO MAIN

:MAIN
REM --------- Connect to the network to get zipped stuff
PROMPT $p$g
SET TEMP=%ramdisk%
SET TMP=%ramdisk%

MKDIR %ramdisk%NET
MKDIR %ramdisk%NCDOS
MKDIR %ramdisk%DOS
MKDIR %ramdisk%4DOS
PATH=%ramdisk%;%ramdisk%NET;%ramdisk%NCDOS;%ramdisk%DOS;%ramdisk%4DOS;A:\

COPY A:\PKUNZJR.COM %ramdisk%DOS

COPY A:\NET.ZIP %ramdisk%NET

%ramdisk%
CD %ramdisk%NET
PKUNZJR NET.ZIP
DEL NET.ZIP

REM The whole reason for this, is that you need to generate a unique NetBIOS name
 ECHO [network] >> SYSTEM.INI
ECHO filesharing=no >> SYSTEM.INI
ECHO printsharing=no  >> SYSTEM.INI
ECHO autologon=yes  >> SYSTEM.INI
ECHO computername=TMP-%_hour-%_minute-%_second >> SYSTEM.INI
ECHO lanroot=%ramdisk%NET  >> SYSTEM.INI
ECHO username=TEST  >> SYSTEM.INI
ECHO workgroup=ACME  >> SYSTEM.INI
ECHO reconnect=no  >> SYSTEM.INI
ECHO directhost=no  >> SYSTEM.INI
ECHO dospophotkey=N  >> SYSTEM.INI
ECHO lmlogon=0  >> SYSTEM.INI
ECHO logondomain=MYCOMPANY  >> SYSTEM.INI
ECHO preferredredir=full  >> SYSTEM.INI
ECHO autostart=full  >> SYSTEM.INI
ECHO maxconnections=8  >> SYSTEM.INI
ECHO [network drivers]  >> SYSTEM.INI
ECHO netcard=El90x.dos  >> SYSTEM.INI
ECHO transport=tcpdrv.dos,nemm.dos  >> SYSTEM.INI
ECHO devdir=%ramdisk%NET  >> SYSTEM.INI
ECHO LoadRMDrivers=yes  >> SYSTEM.INI

%ramdisk%
CD %ramdisk%NET
%ramdisk%net\net initialize
%ramdisk%net\netbind.com
%ramdisk%net\umb.com
%ramdisk%net\tcptsr.exe
%ramdisk%net\tinyrfc.exe
%ramdisk%net\nmtsr.exe
%ramdisk%net\emsbfr.exe

%ramdisk%net\net start
%ramdisk%net\net use y: \\MIS\IMAGES

COPY Y:\DOSUTILS.ZIP %ramdisk%DOS > NUL
COPY Y:\NCDOS.ZIP %ramdisk%NCDOS > NUL

%ramdisk%
CD %ramdisk%DOS
PKUNZJR DOSUTILS.ZIP
DEL DOSUTILS.ZIP

%ramdisk%
CD %ramdisk%NCDOS
PKUNZJR NCDOS.ZIP
DEL NCDOS.ZIP

MOUSE.COM

goto %config%
:NOCD
GOTO CONFIGURE

:CD14
:CD15
LH MSCDEX.EXE /D:mscd001 /M:8

:CONFIGURE
LH SMARTDRV.EXE /X
LH KEYB FR

REM CLS

NET USE

ECHO @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
ECHO Need a text editor and unzipper? Norton Commander to the rescue!
ECHO @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

:END
 

NET.ZIP

This a compressed file that contains all the stuff you need to connect to a remote TCP/IP host with a 3Com 905B network card. The extra SYSTEM.INI file is created live in AUTOEXEC.BAT.

11/18/96  01:38a                   817 lmhosts
11/18/96  01:38a                   395 networks
11/18/96  01:38a                   795 protocol
11/18/96  01:38a                   840 wfwsys.cfg
11/18/96  01:38a                 8,513 netbind.com
11/18/96  01:38a                 3,325 umb.com
11/10/99  11:59a                     0 CONNECT.DAT
04/17/98  04:15p                48,448 EL90X.DOS
11/18/96  01:38a                 2,619 nemm.dos
11/18/96  01:38a                21,940 protman.dos
11/18/96  01:38a                 4,174 tcpdrv.dos
11/18/96  01:38a                 4,294 emsbfr.exe
11/18/96  01:38a               450,342 net.exe
11/18/96  01:38a                22,826 nmtsr.exe
11/18/96  01:38a                13,782 protman.exe
11/18/96  01:38a                71,040 tcptsr.exe
11/18/96  01:38a                37,024 tinyrfc.exe
11/18/96  01:38a                 1,531 setup.inf
11/18/96  01:38a                 1,477 wcsetup.inf
10/11/99  12:30p                   425 protocol.ini
11/18/96  01:38a                   233 tcputils.ini
11/18/96  01:38a                76,234 net.msg
11/18/96  01:38a               123,066 neth.msg
11/18/96  01:38a                 4,468 ndishlp.sys

Resources